For systems at CERN, it may be more appropriate to access the source files over NFS from asisnfs. In this case, we procede as above except that we do not need to copy the .cra and .car files from VXCERN or asisftp. Instead, we modify our LOGIN.COM as shown below to NFS mount the appropriate asis file system.
CERNLIB LOGIN.COM to access sources over NFS from asisnfs
$!
$! Command file to define environment for CERNLIB installation
$! on AXCLIB (Alpha system)
$!
$! N.B. before running this command file, the following must have
$! been performed:
$!
$! 1) The root for the CERNLIB installation must be setup.
$!
$! On the CNLAVC, the CERNLIB tree is installed on
$! VSCLIB$USER1.
$!
$! e.g. CREATE/DIRECTORY VSCLIB$USER1:[CERNLIB]
$!
$! CREATE/DIRECTORY VSCLIB$USER1:[CERNLIB.CERNAXP]
$!
$! These directory names are arbitrary. One could equally
$! well use
$!
$! CREATE/DIRECTORY VSCLIB$USER1:[FRODO]
$!
$! CREATE/DIRECTORY VSCLIB$USER1:[FRODO.BAGGINS]
$!
$! 2) The subdirectory for the appropriate version must be created.
$!
$! e.g. CREATE/DIRECTORY VSCLIB$USER1:[CERNLIB.CERNAXP.94A]
$!
$! Again, this directory name is arbitrary. One could have used
$! NEW, 93D, GLONK etc.
$!
$! 3) The subdirectories [.MGR] and [.EXE] must be created.
$!
$! e.g. CREATE/DIRECTORY VSCLIB$USER1:[CERNLIB.CERNAXP.94A.MGR]
$!
$! e.g. CREATE/DIRECTORY VSCLIB$USER1:[CERNLIB.CERNAXP.94A.EXE]
$!
$! 4) The command files in VXCERN::CERN_ROOT:[EXE] and
$! VXCERN::CERN_ROOT:[MGR] must be copied
$! to the appropriate subdirectory.
$!
$! 5) Finally, the files VXCERN::CERN_ROOt:[MGR]*.FOR should
$! be retrieved and compiled. MAIN_CERNLOGIN.FOR includes
$! CERN_ROOT:[MGR]CERNLOGIN.FOR. As CERN_ROOT is not defined
$! at this stage, simply edit the file and include CERNLOGIN.FOR
$! directly.
$!
$! If you cannot access the CERN sources via NFS, the following
$! steps are also required.
$!
$! a) Create the subdirectories [.SRC] and [.SRC.CAR]
$!
$! b) Copy the .CAR and .CRA files from asisftp or VXCERN
$! to the [.SRC.CAR] directory.
$!
$! c) Remove all references to NFS below.
$!
$! ===============================================================
$!
$! Mount /asis/share tree using NFS. This avoids us having to copy
$! the .CAR and .CRA files locally
$!
$ if f$trnlnm("asis_share") .eqs. "" then nfsmount/soft asisnfs:"/asis/share" -
asis_share
$ nfsdev = f$getdvi("ASIS_SHARE","FULLDEVNAM")
$ define/sys/exec nfscern 'nfsdev'[cern.] /trans=(conc,term)
$!
$! Set the CERNLIB level
$!
$ cern_level :== 94a
$!
$! Define the CERN and CERN_ROOT logical names
$!
$ define/SYS/EXEC/TRANS=(CONCEALED,TERMINAL) -
cern _$177$dka300:[cernlib.cernaxp.],'nfsdev'[cern.]
$!
$ define/SYS/EXEC/TRANS=(CONCEALED,TERMINAL) -
cern_root _$177$dka300:[cernlib.cernaxp.'cern_level'.],-
'nfsdev'[cern.'cern_level'.]
$!
$! For Alpha, need also CERNAXP
$!
$ define/SYS/EXEC/TRANS=(CONCEALED,TERMINAL) -
cernaxp _$177$dka300:[cernlib.cernaxp.]
$!
$! Define various symbols required by the CERNLIB installation
$! (and CERNLIB users)
$!
$ run main_cernlogin
$!
$! Reassert the CERNLIB level (MAIN_CERNLOGIN sets it to PRO)
$!
$ cern_level :== 94a
$!
$! Set the Program Library Installation Environment
$!
$ @cern:['cern_level'.mgr]plienv
$!
$! Override the settings of the following symbols made
$! by MAIN_CERNLOGIN.EXE
$!
$! We must also install these files...
$!
$ ycompare :== $cern:['cern_level'.exe]ycompare
$ yedit :== $cern:['cern_level'.exe]yedit
$ yfrceta :== $cern:['cern_level'.exe]yfrceta
$ yindex :== $cern:['cern_level'.exe]yindex
$ ylist :== $cern:['cern_level'.exe]ylist
$ ypatchy :== $cern:['cern_level'.exe]ypatchy
$ ysearch :== $cern:['cern_level'.exe]ysearch
$ yshift :== $cern:['cern_level'.exe]yshift
$ ytobcd :== $cern:['cern_level'.exe]ytobcd
$ ytobin :== $cern:['cern_level'.exe]ytobin
$ ytoceta :== $cern:['cern_level'.exe]ytoceta
$!
$ yexp*and :== @cern:['cern_level'.exe]yexpand
$!
$ fcasplit :== $cern:['cern_level'.exe]fcasplit
$!
$! Private symbols
$!
$ ed*it :== edit/tpu/section=sys$login:eve
$ t*ype :== type/page